Trading Viewのインジケーターにアラート機能を追加するPineスクリプト

トレーディングビューでアラート機能を使う
Pineスクリプトを使ってインジケーターにアラート条件を追加する
1. Pineスクリプトでアラート条件を追加する関数「alertcondition」
MACDにアラート条件を追加したインジケーターの作成例
1. アラート条件、設定部分のコード解説
2. Pineスクリプトで作成したアラートの使い方
トレーディングビューのアラート機能の注意点
1. アラート機能は自動では設定されない
2. プランによってアラート数、期限に違いがある

トレーディングビューでアラート機能を使う

膨大な数ある金融商品の値動きを日々パソコン画面と向き合いチェックし続けるのはとても大変です。そんな我々投資家にって欠かせないのが「アラート機能」。このアラート機能を上手に使いこなせばトレードの負担を軽減するだけでなく、エントリーのチャンスを見逃すことがなくなります。

特にトレーディングビューのアラート機能は非常に優秀で設定価格に到達したときにアラートを発信するだけでなく、SMA（単純移動平均線）のクロス時などインジケーターを組み合わせて使うことができます。

アラートの設定方法は、画面右のメニューバーから

①アラートマークを選択

②アラートを作成

の手順で作成します。

Pineスクリプトを使ってインジケーターにアラート条件を追加する

通常のアラート作成は特定の値や内蔵されたインジケーターを組み合わせて作成します。これだけでも十分に実用的なアラートを作成することができます。

更にPineスクリプトで作成したオリジナルのインジケーターにアラート条件を追加することで、より複雑で自分の思い通りのアラートを設定することが可能になります。

Pineスクリプトでアラート条件を追加する関数「alertcondition」

Pineスクリプトでアラート条件を設定するにはalertcondition関数を使います。

//alertconditionの書き方
alertcondition(condition, title, message)

alertconditionに使用する引数はcondition、title、messageの3つです。

引数：condition

アラート発生のトリガー条件を設定する必須の引数です。アラート発生の判定は理論式のTrue、Falseで行い、Trueの場合にアラートが発生します。

引数：title

設定したアラートの名前を入力します。必須の引数ではなく省略も可能です。

引数：message

アラート発生時に表示するテキストメッセージを入力します。この引数にはシンボル名、価格、出来高を表示させる変数も設定することができます。titleと同様に必須の引数ではなく省略も可能です。

MACDにアラート条件を追加したインジケーターの作成例

実際にalertconditionを使ってインジケーターを作成してみましょう。

今回はPineスクリプト入門#16|MACDと他のインジケーターを組み合わせたバックテストで作成したストラテジーコードを改良してインジケーターを作りました。

以下が完成したインジケーターのコードです。

//@version=4
study("macd+SMA", overlay=true)

//インプット設定-----------------------------------------------
fast_len = input(12, title="短期")
slow_len = input(26, title="長期")
signal_len = input(9, title="シグナル")
macd_src = input(close, title="macd_source", type=input.source)
sma_src = input(close, title="sma_source", type=input.source)

//MACD---------------------------------------------------------
MACD = ema(macd_src, fast_len) - ema(macd_src, slow_len)
signal = ema(MACD, signal_len)

//SMA-----------------------------------------------
SMA = sma(sma_src, 200)

//アラート条件-------------------------------------------------
long_condition = close > SMA and crossover(MACD, signal)
short_condition = close <= SMA and crossunder(MACD, signal)

//アラート設定-------------------------------------------------
alertcondition(long_condition, title="long_alert", message="買いエントリー")
alertcondition(short_condition, title="short_alert", message="売りエントリー")

plotshape(long_condition, title="buy", text="Buy", color=color.green, style=shape.labelup, location=location.belowbar, size=size.small, textcolor=color.white, transp=0)
plotshape(short_condition, title="sell", text="Sell", color=color.red, style=shape.labeldown, location=location.abovebar, size=size.small, textcolor=color.white, transp=0)

アラート条件、設定部分のコード解説

//アラート条件-------------------------------------------------
long_condition = close > SMA and crossover(MACD, signal)
short_condition = close <= SMA and crossunder(MACD, signal)

アラートを発生させる条件を入力しています。それぞれ以下の意味になります。

・long_conditionは終値がSMA200よりも高く、MACD線がsignal線を上抜けした時。

・short_conditionは終値がSMA200以下でMACD線がsignal線を下抜けした時。

//アラート設定-------------------------------------------------
alertcondition(long_condition, title="long_alert", message="買いエントリー")
alertcondition(short_condition, title="short_alert", message="売りエントリー")

先ほどのアラート条件をアラート作成画面で設定できるようにするためalertconditionを使います。

アラート発生のトリガーはアラート条件で作成したlong_condition、short_conditionです。

タイトルはそれぞれ「long_alert」と「short_alert」にしました。

アラート発生時のメッセージはそれぞれ「買いエントリー」「売りエントリー」としました。

Pineスクリプトを使ったアラート設定のコードは以上です。