TradingView無料プランで3つ以上のインジケーターを表示させる方法

Trading Viewのプラン別特徴
無料プランだとインジケーター数が足りない…
Trading Viewでは無料プランでもインジケーターを自作できる
Pineスクリプトで3つ以上のインジケーターを表示できる！
Pineスクリプトで作成したオリジナルのインジケーターを紹介
1. バージョン5のコード
おすすめの証券会社

Trading Viewのプラン別特徴

Trading Viewでは以下4つのプランがあります。

Basic（無料）
Pro（14.95ドル）
Pro+（29.95ドル）
Premium（59.95ドル）

有料プランになるとチャート上に広告が表示されなかったり、チャートレイアウト保存数が増えたり、出来高プロファイルが使えたりと使い勝手がよくなります。

Trading Viewのチャートは高機能かつ使いやすいので無料プランでも登録する価値はあります。

ただ、無料プランで最も不便な点はインジケーターを3つしか表示できないことです。

無料プランだとインジケーター数が足りない…

表示できるインジケーターが3個って少ないですよね。

私は有料プランの「Pro」を使っていますが、よく使うインジケーターは以下の6つなのでこのままだと今のプランでも足りていないんです（Proの表示できるインジケーターは5個まで）。プランによってインジケーターの表示できる数が限られるのは不便だなと思ってしまいます。

・移動平均線　短期
・移動平均線　中期
・移動平均線　長期
・ボリンジャーバンド
・MACD
・RSI

Trading Viewでは無料プランでもインジケーターを自作できる

Trading Viewは独自のプログラミング言語である「Pineスクリプト」を使うことでオリジナルのインジケーターを作ることが可能です。

例えば、Pineスクリプトで単純移動平均線を作成すると以下のコードになります。

//単純移動平均線の書き方
//@version=4
study("単純移動平均線", overlay=true)
src = input(close, title="ソース")
len = input(25, title="期間")
SMA = sma(src, len)
plot(SMA)

たったこれだけで単純移動平均線がチャート上に表示できるんです。Pineスクリプトはチャートに特化したプログラミング言語なので簡単にインジケーターを自作することができます。

Pineスクリプトで3つ以上のインジケーターを表示できる！

先ほど紹介したPineスクリプトですが、チャート上では1つのプログラムにつき1つのインジケーターとしてカウントされます。
つまり、1つのプログラムに複数のインジケーターを組み込んでも1つのインジケーターとして認識されるため、これを利用すれば無料プランでも実質3つ以上のインジケーターを表示させることが可能になります。

例えば、3つの単純移動平均線を表示させるインジケーターは以下のコードになります。

//3本の単純移動平均線の書き方
//@version=4
study("単純移動平均線3本表示", overlay=true)
src = input(close, title="ソース")
len_A = input(25, title="期間A")
len_B = input(50, title="期間B")
len_C = input(100, title="期間C")
SMA_A = sma(src, len_A)
SMA_B = sma(src, len_B)
SMA_C = sma(src, len_C)
plot(SMA_A)
plot(SMA_B)
plot(SMA_C)

Pineスクリプトで作成したオリジナルのインジケーターを紹介

私が普段使っているインジケーターを紹介します。

このスクリプトは、単純移動平均線3本とボリンジャーバンドを表示させるインジケーターになります。

もちろんこのスクリプトは1つのインジケーターとしてカウントされるので、無料プランでもあと2つインジケーターを追加することができます。

無料プランの方は是非試してみてください！

※Pineスクリプトを使用するにはPCでの操作が必要です。Pineスクリプト導入方法がわからない方はこちらの記事を参考にしてみてください。

//@version=4
study("SMA3+BB", overlay=true, shorttitle="MA4+BB")

//インプット設定-----------------------------------------------
len_A = input(25, title="MA_A期間")
len_B = input(50, title="MA_B期間")
len_C = input(100, title="MA_C期間")
len_dev = input(25, title="標準偏差_期間")
src_A = input(close, title="Aソース", type=input.source)
src_B = input(close, title="Bソース", type=input.source)
src_C = input(close, title="Cソース", type=input.source)
src_dev = input(close, title="標準偏差ソース", type=input.source)
mult_2 = input(2.0, minval=0.001, maxval=50, title="±2σ")
mult_3 = input(3.0, minval=0.001, maxval=50, title="±3σ")

MA_A = sma(src_A, len_A)
MA_B = sma(src_B, len_B)
MA_C = sma(src_C, len_C)

//標準偏差計算------------------------------------------------
dev_2 = mult_2*stdev(src_dev, len_dev)
dev_3 = mult_3*stdev(src_dev, len_dev)
base_line = sma(src_dev, len_dev)
sigma_p2 = base_line + dev_2
sigma_p3 = base_line + dev_3
sigma_m2 = base_line - dev_2
sigma_m3 = base_line - dev_3

//プロット用--------------------------------------------------
plot(MA_A, color=color.blue, title="MA_A")
plot(MA_B, color=color.orange, title="MA_B")
plot(MA_C, color=color.red, title="MA_C")
plot(sigma_p2, color=color.green, title="±2σ")
plot(sigma_m2, color=color.green, title="±2σ")
plot(sigma_p3, color=color.green, title="±3σ")
plot(sigma_m3, color=color.green, title="±3σ")

バージョン5のコード

記事中はバージョン4で記載しています。

以下のコードはバージョン5を使用した場合です。

//@version=5
indicator('SMA3+BB', overlay=true, shorttitle='MA4+BB')

//インプット設定-----------------------------------------------
len_A = input(25, title='MA_A期間')
len_B = input(50, title='MA_B期間')
len_C = input(100, title='MA_C期間')
len_dev = input(25, title='標準偏差_期間')
src_A = input(close, title='Aソース')
src_B = input(close, title='Bソース')
src_C = input(close, title='Cソース')
src_dev = input(close, title='標準偏差ソース')
mult_2 = input.float(2.0, minval=0.001, maxval=50, title='±2σ')
mult_3 = input.float(3.0, minval=0.001, maxval=50, title='±3σ')

MA_A = ta.sma(src_A, len_A)
MA_B = ta.sma(src_B, len_B)
MA_C = ta.sma(src_C, len_C)

//標準偏差計算------------------------------------------------
dev_2 = mult_2 * ta.stdev(src_dev, len_dev)
dev_3 = mult_3 * ta.stdev(src_dev, len_dev)
base_line = ta.sma(src_dev, len_dev)
sigma_p2 = base_line + dev_2
sigma_p3 = base_line + dev_3
sigma_m2 = base_line - dev_2
sigma_m3 = base_line - dev_3

//プロット用--------------------------------------------------
plot(MA_A, color=color.new(color.blue, 0), title='MA_A')
plot(MA_B, color=color.new(color.orange, 0), title='MA_B')
plot(MA_C, color=color.new(color.red, 0), title='MA_C')
plot(sigma_p2, color=color.new(color.green, 0), title='±2σ')
plot(sigma_m2, color=color.new(color.green, 0), title='±2σ')
plot(sigma_p3, color=color.new(color.green, 0), title='±3σ')
plot(sigma_m3, color=color.new(color.green, 0), title='±3σ')